How to check if string contains a substring in terraform interpolation?

Question

How do you check if a terraform string contains another string?

For example, I want to treat terraform workspaces with "tmp" in the name specially (e.g. allowing rds instances to be deleted without a snapshot), so something like this:

locals
{
  is_tmp = "${"tmp" in terraform.workspace}"
}

As far as I can tell, the substr interpolation function doesn't accomplish this.

Answer 1

For terraform 0.12.xx apparently you are suppose to use regexall to do this.

From the manual for terraform 0.12.XX: regexall() documentation

regexall can also be used to test whether a particular string matches a given pattern, by testing whether the length of the resulting list of matches is greater than zero.

Example from the manual:

> length(regexall("[a-z]+", "1234abcd5678efgh9"))
2

> length(regexall("[a-z]+", "123456789")) > 0
false

Example applied to your case in terraform 0.12.xx syntax should be something like:

locals
{
  is_tmp = length(regexall(".*tmp.*", terraform.workspace)) > 0
}

It also specifically says in the manual not to use "regex" but instead use regexall.

If the given pattern does not match at all, the regex raises an error. To test whether a given pattern matches a string, use regexall and test that the result has length greater than zero.

As stated above this is because you will actually get an exception error when you try to use it in the later versions of 0.12.xx that are out now when you run plan. This is how I found this out and why I posted the new answer back here.

Answer 2

You can indirectly check for substrings using replace, e.g.

locals
{
  is_tmp = "${replace(terraform.workspace, "tmp", "") != terraform.workspace}"
}

Answer 3

Like @MechaStorm, with Terrafor 0.12.7+ you can use regex to return a Boolean value if your string contains a particular substring

locals {
  is_tmp = contains(regex("^(?:.*(tmp))?.*$",terraform.workspace),"tmp")
}

The regex query returns a list of capture groups for any characters before tmp, tmp if found, any characters after tmp. Then contains looks for "tmp" in the list and returns true or false. I am using this type of logic in my own terraform.

Answer 4

Length of the list produced by split function is greater than one when separtor is a substring.

locals {
  is_tmp = length(split("tmp", terraform.workspace)) > 1
}

Answer 5

Use replace( string, search, replace ) as in the snippet:

// string contains ABBA = result is ABBA
output "match" {
  value = "${ replace("xxxABBAyyy", "/(?:.*)(ABBA)(?:.*)/", "$1") }"
}
// string doesn't contain ABBA = result is original string
output "no_match" {
  value = "${ replace("xxxBABAyyy", "/(?:.*)(ABBA)(?:.*)/", "$1")}"
}
// string contains ABBA (ingorecase) = result is AbBA
output "equals_ignorecase" {
  value = "${ replace("xxxAbBAyyy", "/(?:.*)((?i)ABBA)(?:.*)/", "$1")}"
}

An output of terraform apply is:

Outputs:

equals_ignorecase = AbBA
match = ABBA
no_match = xxxBABAyyy

Answer 6

In terraform 0.12.7, we now have regex . This may help simplify some code and make it readable to some (perhaps?)

> regex("[a-z]+", "53453453.345345aaabbbccc23454")
aaabbbccc

Answer 7

I use this way to check if bucket name start with test-tmp eg. test-tmp, test-tmp-app1, test-tmp-db1 etc..

is_test_bucket = can(regex("^(test-tmp){1}($|-{1}.*$)", var.bucket_name))